黑暗勋章的实例脚本(四)
[@黑暗宝石]
{
#SAY
魔道修行注重炼器，将心魔附魔在首饰上，只能临时提升首\
饰的威力，非长久之计。用残留在首饰上的黑暗魔力来修炼武器\
，可以<COLOR=GREEN 永久提升首饰威力>，这是魔道修行的高级炼器方法。\
用黑暗魔力修炼首饰，要看造化，但你可以放心的是就算<COLOR=GREEN 失>\
<COLOR=GREEN 败了，首饰也不会破碎>。你想试试看么？\
<我要修炼勋章或宝石的黑暗属性/@升级宝石勋章>\
<我想多了解一点再决定/@多介绍>\
<增加装备黑暗魔力/@购买黑暗>
[@购买黑暗]
装备的黑暗魔力可以在游戏中杀怪、参加活动、做任务等获\
得！还可以用镇魔符直接点在附魔后的装备上增加！\
因为<COLOR=GREEN 没有附魔过的装备不能直接使用镇魔符增加黑暗魔力>，\
所以如果你想给你的装备增加黑暗魔力的话，就可以拿镇魔符来\
找我，我就帮你把镇魔符里的黑暗力量给你增加到你指定的装备\
上去！<COLOR=GREEN 每张镇魔符可增加80到90点左右的黑暗魔力！>\\
我要<用镇魔符增加装备黑暗魔力/@增加y>\
<返回/@main>
[@增加y]
#ACT
checkitembox 放入你想增加的装备 1 141
[@getboxitem141]
#IF
CHECKVARLIST $CHECKBOXITEM.STDMODE ..\宝石类型.txt
#ACT
GOTO @keieijia
#ELSEACT
messagebox 当前物品不能增加黑暗魔力！
break
[@keieijia]
#IF
checkitem 镇魔符 1
#ACT
take 镇魔符 1
UPGRADECHECKITEMBOX 19 + 85
SENDMSG 5 装备的黑暗魔力提升了！
#ELSEACT
messagebox 你包内没有镇魔符，不能增加黑暗魔力！\ \镇魔符可以在商城里用元宝购买！
break
[@多介绍]
每次升级，不管成功失败，都要消耗掉首饰上的黑暗魔\
力。首饰现有黑暗属性的越高，升级一次消耗的黑暗魔力也\
越多。注意，<COLOR=GREEN 首饰>蕴涵的灵力有限，最多只能<COLOR=GREEN 增加3点威力>。\\
<升级成功有什么好处？/@jf123>\
<升级失败有什么损失？/@gfdfsg>\
<我能用黑暗魔力升级其它装备吗？/@4563h>\
<返回/@升级首饰> <知道了/@exit>
[@jf123]
若升级成功，则首饰上会增加0—1的黑暗属性，战士首\
饰得到黑暗攻击属性，法师首饰得到黑暗魔法属性，道士首\
饰得到黑暗道术属性。\
呵呵，黑暗属性是永久的，不是临时的！\\
<返回/@多介绍>
[@gfdfsg]
若升级失败，则首饰上已有的黑暗属性可能会减少，但\
你大可放心的是，黑暗魔力不能冲破首饰蕴涵的灵力，所以\
你的首饰再怎么升也不会破碎。\\
<返回/@多介绍>
[@4563h]
用黑暗魔力升级首饰，这个俺在行，但是护甲、头盔和\
武器这些精细的玩意，俺可不懂。你去问问<COLOR=GREEN 服装店和铁匠铺>\
的人吧，也许他们也掌握了黑暗魔力升级装备的诀窍呢！\\
<返回/@多介绍>
[@升级宝石勋章]
#ACT
checkitembox 放入你想升级的勋章或宝石 1 48
[@getboxitem48]
#IF
CHECKVARLIST $CHECKBOXITEM.STDMODE ..\宝石类型.txt
#ACT
#ELSEACT
messagebox 你所放入的物品不是宝石或勋章类型！不能进行黑暗属性升级！
break
#IF
checkjob warrior
#ACT
MOV P3 $CHECKBOXITEM.DARKPOINT(0)
MOV P4 $CHECKBOXITEM.DARKPOINT(2)
CALCVAR HUMAN SCH = $CHECKBOXITEM.DARKPOINT(2)
CALCVAR HUMAN SCH * 300
CALCVAR HUMAN SCH + 300
GOTO @BAOSHIXUZ
break
#IF
checkjob wizard
#ACT
MOV P3 $CHECKBOXITEM.DARKPOINT(0)
MOV P4 $CHECKBOXITEM.DARKPOINT(4)
CALCVAR HUMAN SCH = $CHECKBOXITEM.DARKPOINT(4)
CALCVAR HUMAN SCH * 300
CALCVAR HUMAN SCH + 300
GOTO @BAOSHIXUZ
break
#IF
checkjob taoist
#ACT
MOV P3 $CHECKBOXITEM.DARKPOINT(0)
MOV P4 $CHECKBOXITEM.DARKPOINT(6)
CALCVAR HUMAN SCH = $CHECKBOXITEM.DARKPOINT(6)
CALCVAR HUMAN SCH * 300
CALCVAR HUMAN SCH + 300
GOTO @BAOSHIXUZ
break
[@BAOSHIXUZ]
#IF
LARGE P4 2
#ACT
messagebox 当前装备的黑暗属性值已经达到最高限制3点了，不能进行升级！
break
#IF
SMALL P3 $HUMAN(SCH)
#ACT
messagebox 当前装备黑暗魔力值不足<$HUMAN(SCH)>，不能进行升级！\ \
break
#IF
checkitem 幸运符 6
#ACT
take 幸运符 6
GOTO @升级成功
break
#IF
LARGE P4 0
#ACT
GOTO @BOAOSL1
break
#ELSEACT
GOTO @BOAOSL2
break
[@BOAOSL1]
#IF
random 50
#ACT
GOTO @升级成功
break
#ELSEACT
GOTO @SHENGJISHIL
break
[@BOAOSL2]
#IF
random 5
#ACT
GOTO @SHENGJISHIL
break
#ELSEACT
GOTO @升级成功
break
[@升级成功]
#IF
checkjob warrior
CHECKVAR HUMAN SCH > 100
#ACT
UPGRADECHECKITEMBOX 19 - $HUMAN(SCH)
UPGRADECHECKITEMBOX 21 + 1
SENDMSG 5 恭喜您，您的首饰充分炼化了黑暗魔力，升级成功了！
messagebox 恭喜您，您的首饰充分炼化了黑暗魔力，升级成功了！
break
#IF
checkjob wizard
CHECKVAR HUMAN SCH > 100
#ACT
UPGRADECHECKITEMBOX 19 - $HUMAN(SCH)
UPGRADECHECKITEMBOX 23 + 1
SENDMSG 5 恭喜您，您的首饰充分炼化了黑暗魔力，升级成功了！
messagebox 恭喜您，您的首饰充分炼化了黑暗魔力，升级成功了！
break
#IF
checkjob taoist
CHECKVAR HUMAN SCH > 100
#ACT
UPGRADECHECKITEMBOX 19 - $HUMAN(SCH)
UPGRADECHECKITEMBOX 25 + 1
SENDMSG 5 恭喜您，您的首饰充分炼化了黑暗魔力，升级成功了！
messagebox 恭喜您，您的首饰充分炼化了黑暗魔力，升级成功了！
break
[@SHENGJISHIL]
#IF
TRUE
#ACT
UPGRADECHECKITEMBOX 19 - $HUMAN(SCH)
SENDMSG 5 很遗憾！您的首饰黑暗属性升级失败了！如果你放6张幸运符在[背包里]，黑暗属性升级将是100%成功！
break
}
| 
| 网站首页 
| 联系我们 
| 传世一条龙